Commons Wikipédia open data données Wikidata SPARQL linked open data

Pense-bête et compilation de requêtes des données de Wikidata, portant sur le patrimoine et la culture, modifiables et remixables à souhait, d'après les formidables #1jour1requête de @belett

Les requêtes sont en clair. Les liens renvoient vers le requêteur SPARQL. La requête se lance en cliquant sur le bouton bleu (1). Au survol, une bulle d'aide décrit les propriétés (P...) et les éléments (Q...) (2). Ces propriétés et éléments peuvent être modifiés facilement en utilisant la saisie par auto-complétion (ctrl + barre espace). Le mode d'affichage de la visualisation peut être modifié (liste, mosaïque, diagramme... selon les paramètres permis par la requête) (3).

 

sparql wd lancer 

Mais pourquoi ces copier-coller de requêtes, alors qu'il y a des ressources pour apprendre le SPARQL ??? D'abord à titre de pense-bête perso des supers requêtes patrimoniales de @belett, de crainte qu'elles ne qui ne disparaissent corps et âme avec feu-Twitter (pour l'âme de Twitter, c'est déjà trop tard). Dans le monde du numérique et du web, il n'y a par ailleurs souvent rien de mieux pour apprendre que de modifier des copier-coller de code déjà faits, en changeant les paramètres (surtout quand on n'a pas le temps de se plonger dans lesdites ressources, tutoriels et autres supers vidéos). Aveu : j'ai paramétré et généré cette carte des femmes ayant un identifiant FranceArchives (avec calque par siècle) à partir de la requête cartographiant Carte des lieux de naissance des joueurs de l'ASM...

Plus d'une soixantaine de requêtes sont répertoriées ci-après. Afin de s'y retrouver, elles ont été triées par type de visualisation (liste, mosaïque d'images, graphiques, cartes, ...)... même si toute visualisation n'est en fait qu'une liste de données visualisée autrement. Une fois "habitué.e." à changer quelques éléments, les requêtes SPARQL en clair permettent de chercher les formulations pour grouper, trier, paramétrer des conditions, etc.

 

PS : le tropisme auvergnato-breton a une double explication (Nicolas Vigneron a été wikimédien en résidence en Auvergne puis au musée de Bretagne à Rennes).

 

Sommaire

Des listes (affichage par défaut) - Des images (ImageGrid) - Des graphiques (LineChart, BubbleChart, BarChart) - Des cartes (Map) - Des frises chronologiques  (Timeline) - Autres - Bonus

 

Pour aller plus loin

 

Requêtes

Des listes

 

 

documents du fonds Boyer par décennie

Liste des personnes nées dans le Puy-de-Dôme et en novembre (lien)

SELECT ?person ?personLabel ?dateNaissance ?age WHERE {
?person wdt:P19/wdt:P131* wd:Q12694 ; wdt:P569 ?dateNaissance .
FILTER ( MONTH(?dateNaissance) = 11 )
BIND ( FLOOR( ( NOW() - ?dateNaissance) / 365 ) AS ?age )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?age

 

Liste de textes disponibles sur la Wikisource en français écrits par des personnes nées dans le Puy-de-Dôme

Liste de textes disponibles sur la Wikisource en français écrits par des personnes nées dans le Puy-de-Dôme (lien)

#title:Textes sur la Wikisource en français par des personnes nées dans le Puy-de-Dôme
SELECT DISTINCT ?personLabel ?bookLabel ?page WHERE {
?book wdt:P50 ?person.
?person wdt:P19 ?place.
?place wdt:P131+ wd:Q12694.
?page schema:about ?book .
?page schema:isPartOf <https://fr.wikisource.org/> .
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY ?personLabel

 

Emplacement de quelques sépultures au cimetière des Carmes de Clermont-Ferrand

Emplacement de quelques sépultures au cimetière des Carmes de Clermont-Ferrand (lien)

#title:Emplacement des sépultures au cimetière des Carmes
SELECT ?personLabel ?emplacement ?date WHERE {
?person p:P119 ?node .
?node ps:P119 wd:Q2972588 .
?node pq:P965 ?emplacement .
?person wdt:P570 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?date 

 

 

 

Liste des personnes (principalement des martyrs et des saint-e-s) dont c'est la fête aujourd'hui

Liste des personnes (principalement des martyrs et des saint-e-s) dont c'est la fête aujourd'hui. Bonus : cette requête est mise à jour automatiquement chaque jour ! (lien)

#title:Liste des personnes dont c'est la fête aujourd'hui (mis à jour quotidiennement automatiquement)
SELECT ?feteLabel ?item ?itemLabel WHERE {
  BIND ( NOW() AS ?now )
  BIND ( STR( MONTH(?now) ) AS ?mois )
  BIND ( STR( DAY(?now) ) AS ?jour )
  ?itemMois p:P279 ?nodeM .
  ?nodeM ps:P279 wd:Q18602249 .
  ?nodeM pq:P1545 ?mois .
  ?fete p:P361 ?nodeF .
  ?nodeF ps:P361 ?itemMois .
  ?nodeF pq:P1545 ?jour .
  ?item wdt:P841 ?fete .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Propriétés Wikidata les plus couramment utilisées sur des éléments situés en Bretagne avec ou sans libellé en breton (lien)

SELECT ?property ?label (COUNT(?item) AS ?nb) WHERE {
?prop rdf:type wikibase:Property;
wikibase:directClaim ?property.
OPTIONAL {
?prop rdfs:label ?label.
FILTER((LANG(?label)) = "br")
}
?item (wdt:P131+) wd:Q12130;
?property _:b0.
}
GROUP BY ?property ?label
ORDER BY DESC (?nb)  

 

Liste des articles situés dans le Puy-de-Dôme avec une page sur la Wikipédia en anglais mais pas en français (lien)

#title: Articles dans le Puy-de-Dôme avec une page sur la Wikipédia en anglais mais pas en français
SELECT ?item ?itemLabel ?pageEN WHERE {
?item wdt:P131+ wd:Q12694 .
?pageEN schema:about ?item. ?pageEN schema:isPartOf <https://en.wikipedia.org/> .
MINUS { ?pageFR schema:about ?item. ?pageFR schema:isPartOf <https://fr.wikipedia.org/> . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

 

 

Personnes nées un 14 février à Clermont-Ferrand (lien)

#title:Personnes nées un 14 février à Clermont-Ferrand
SELECT ?item ?itemLabel ?date WHERE {
?item wdt:P19/wdt:P131* wd:Q42168 ; wdt:P569 ?date .
FILTER ( DAY(?date) = 14 )
FILTER ( MONTH(?date) = 02 )
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

 

Liste des voies de Clermont-Ferrand portant sur une personne n'ayant pas d'article sur la Wikipédia en français (des suggestions d'idées d'articles à créer ;) ) (lien)

#title: liste des voies de Clermont-Ferrand portant sur une personne n'ayant pas d'article sur la Wikipédia en français
SELECT ?item ?itemLabel ?personne ?personneLabel WHERE {
?item wdt:P31/wdt:P279* wd:Q83620 ; wdt:P131 wd:Q42168 ; wdt:P138 ?personne .
?personne wdt:P31 wd:Q5 .
MINUS { ?article schema:about ?personne ; schema:isPartOf <https://fr.wikipedia.org/> . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 

 

Liste de personnes dont les Archives départementales du Puy-de-Dôme conserve des documents (lien)

#title: "Personnes dont les Archives départementales du Puy-de-Dôme conserve des documents"
SELECT ?item ?itemLabel ?dateN ?dateM ?cote WHERE {
?item p:P485 ?node .
?node ps:P485 wd:Q19606464.
?node pq:P217 ?cote .
OPTIONAL { ?item wdt:P569 ?dateN }
OPTIONAL { ?item wdt:P570 ?dateM }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} 

 

Liste des monuments français sans coordonnées dans Wikidata (lien)

#title: Monuments français sans coordonnées
SELECT DISTINCT ?q ?qLabel ?qDescription WHERE {
?q wdt:P17 wd:Q142 ; wdt:P1435 ?any .
MINUS { ?q wdt:P625 ?coord }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

sparql wd 38Liste de botanistes en lien avec un lieu du Puy-de-Dôme (2-3 trucs inhabituels pour obtenir la liste et le libellé du lien) (lien)

#title: Liste de botanistes en lien avec un lieu du Puy-de-Dôme
SELECT ?q ?qLabel ?lieuNLabel ?nomLienLabel WHERE {
?q wdt:P106 wd:Q2374149 ; ?lien ?lieuN .
?nomLien wikibase:directClaim ?lien .
?lieuN wdt:P131+ wd:Q12694 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }


} 

liste des éléments Wikidata sans image avec suggestion d'illustration(s) issue(s) du fond Boyer

Après import dans Wikidata du fond Boyer, liste des éléments Wikidata sans image avec suggestion d'illustration(s) issue(s) du fond Boyer (lien)

 

#title: Éléments Wikidata sans image avec suggestion d'illustration
SELECT ?personne ?personneLabel ?page (COUNT(?img) AS ?nb) (GROUP_CONCAT(SUBSTR(wikibase:decodeUri(STR(?img)),52)) as ?imgs) WHERE {
?q wdt:P195 wd:Q108427678 ; wdt:P180 ?personne ; wdt:P18 ?img . #image du fond Boyer dépeignant une personne
MINUS { ?personne wdt:P18 [] } #cette personne n'a pas d'image
OPTIONAL { ?page schema:about ?personne ; schema:isPartOf <https://fr.wikipedia.org/> . } #donner le lien vers Wikipédia s'il existe
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?personne ?personneLabel ?page
ORDER BY DESC(?nb) #tri pour mettre les personnes les plus représentées d'abord 

 

Objets de la préhistoire dans l'exposition permanente du musée de Bretagne (lien)

#title: Objets de la préhistoire dans l'exposition permanente du musée de Bretagne
SELECT ?q ?qLabel ?inv ?typeLabel ?longueur ?largeur ?périodeLabel WHERE {
?q wdt:P195 wd:Q3329701 ;
wdt:P31 ?type ;
wdt:P217 ?inv ;
wdt:P2348 ?période ;
wdt:P608 ?expo .
OPTIONAL { ?q wdt:P2043 ?longueur }
OPTIONAL { ?q wdt:P2049 ?largeur }
VALUES ?période { wd:Q44155 wd:Q479505 wd:Q626270 wd:Q7463501 }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}

 

Personnes nées à Rennes, avec leur occupation et par nombre de liens Wikipédia décroissants (et donc leur notoriété...) (lien)

#title:Personnes nées à Rennes, avec leur occupation et par nombre de liens Wikipédia décroissants
SELECT ?q ?qLabel (GROUP_CONCAT(?occupationLabel ; SEPARATOR=", ") as ?occupations) ?nb_liens WHERE {
?q wdt:P19 wd:Q647 ;
wdt:P106 ?occupation ;
wikibase:sitelinks ?nb_liens .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?q rdfs:label ?qLabel .
?occupation rdfs:label ?occupationLabel . }
}
GROUP BY ?q ?qLabel ?nb_liens
ORDER BY DESC(?nb_liens)

 

Journées internationales en mai (lien)

#title: Journées internationales en mai
SELECT ?jourLabel ?dateLabel WHERE {
?jour wdt:P31 wd:Q2558684 ;
wdt:P837 ?date .
?date wdt:P361 wd:Q119 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?date

 

Personnes membres d'une équipe sportive liée à Rennes sans photo (Personnes membres d'une équipe sportive liée à Rennes sans photo )

SELECT DISTINCT ?personne ?personneLabel ?equipeLabel WHERE {
?personne wdt:P54 ?equipe .
?equipe wdt:P641 ?sport ;
?lien wd:Q647 .
MINUS { ?personne wdt:P18 [] }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

Liste des préfets de Bretagne sans illustration (lien)

SELECT DISTINCT ?q ?qLabel ?préfetLabel ?dateN ?dateM WHERE {
VALUES ?préfet { wd:Q62694838 wd:Q64441571 wd:Q65947417 wd:Q40333606 wd:Q65501262 }
?q wdt:P39 ?préfet ; wdt:P569 ?dateN .
OPTIONAL { ?q wdt:P570 ?dateM }
MINUS { ?q wdt:P18 [] }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?dateN

 

Des images

 

Vu la saison et qu'il a neigé hier, une liste d’œuvres représentant la neige (au sens large)

Vu la saison et qu'il a neigé hier, une liste d’œuvres représentant la neige (au sens large) (lien)

#title:Œuvres représentant la neige
#defaultView:ImageGrid
SELECT ?q ?qLabel (SAMPLE(?img) AS ?image) WHERE {
?q wdt:P180 ?depeint ; wdt:P18 ?img .
?depeint ?prop wd:Q7561 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?q ?qLabel

 

 

Galerie d'images d'œuvres du musée d'Art Roger-Quilliot de Clermont-Ferrand

Galerie d'images d'œuvres du musée d'Art Roger-Quilliot de Clermont-Ferrand (lien)

#title:Œuvres du musée d'Art Roger-Quilliot
#defaultView:ImageGrid
SELECT ?item ?itemLabel ?image ?createurLabel WHERE {
?item wdt:P195 wd:Q1495869 ; wdt:P18 ?image .
OPTIONAL { ?item wdt:P170 ?createur }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" . }
} 

 

 

Galerie d'images de fromages produits dans le Puy-de-Dôme


Galerie d'images de fromages produits dans le Puy-de-Dôme (lien)

#defaultView:ImageGrid
SELECT DISTINCT ?objet ?objetLabel ?img WHERE {
?objet wdt:P279* wd:Q10943 ; wdt:P1071/wdt:P131* wd:Q12694 ; wdt:P18 ?img .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

Pour les 217 ans du sacre de Napoléon, une requête #SPARQL #Wikidata montrant toutes les personnes représentées sur le tableau de Jacques-Louis David

Pour les 217 ans du sacre de Napoléon, une requête #SPARQL #Wikidata montrant toutes les personnes représentées sur le tableau de Jacques-Louis David (lien)

#title:Personnes représentées sur le tableau "Le Sacre de Napoléon" du 2 décembre 1804 par Jacques-Louis David
#defaultView:ImageGrid
SELECT ?img ?depeint ?depeintLabel ?depeintDescription WHERE {
wd:Q1231009 wdt:P180 ?depeint .
?depeint wdt:P31 wd:Q5 ; wdt:P18 ?img
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

 

 

Des graphiques

 

 sparql wd 1

Fréquentation des musées Bargoin, Roger-Quilliot et Henri-Lecoq par année (lien)

#defaultView:LineChart
SELECT ?musee ?annee ?visiteurs ?museeLabel WHERE {
{
SELECT ?musee ?annee (AVG(?nb) AS ?visiteurs) WHERE {
{
SELECT ?musee (STR(YEAR(?date)) AS ?annee) ?nb WHERE {
VALUES ?musee { wd:Q3330860 wd:Q1495869 wd:Q3329089 }
?musee p:P1174 ?node.
?node ps:P1174 ?nb ; pq:P585 ?date.
}
}
}
GROUP BY ?musee ?annee
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

sparql wd 3

Diagramme en bulle des sujets les plus représentés dans les documents du fonds Boyer de la bibliothèque du patrimoine de Clermont-Ferrand (lien)

 

#defaultView:BubbleChart
SELECT ?depeintLabel (COUNT(?q) AS ?compte) WHERE {
?q wdt:P195 wd:Q108427678 ; wdt:P180 ?depeint .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?depeintLabel

 

documents du fonds Boyer par décennie

Documents rattachés au fonds Boyer par décennie (lien)

#defaultView:BarChart
SELECT ?décennie (COUNT(?item) AS ?compte) WHERE {
?item wdt:P195 wd:Q108427678 ; wdt:P577 ?date .
BIND ( STR(FLOOR(YEAR(?date)/10)) AS ?décennie )
}
GROUP BY ?décennie 

 

 

 

Diagramme en bulle selon pays de citoyenneté des personnes nées dans le Puy-de-Dôme (hors France)

Diagramme en bulle selon pays de citoyenneté des personnes nées dans le Puy-de-Dôme (hors France) (lien)

#defaultView:BubbleChart
SELECT ?nationalité ?nationalitéLabel (COUNT(?q) AS ?ct) WHERE {
?q wdt:P19/wdt:P131* wd:Q12694 ; wdt:P27 ?nationalité .
MINUS { ?q wdt:P27 wd:Q142 }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?nationalité ?nationalitéLabel

 

 

 diagramme en bulle des prénoms les plus courants (> 5) dans les personnes ayant un élément Wikidata et nées en Auvergne

Diagramme en bulle des prénoms les plus courants (> 5) dans les personnes ayant un élément Wikidata et nées en Auvergne (lien)

#defaultView:BubbleChart
SELECT ?prenomLabel (COUNT(?q) AS ?compte) WHERE {
?q wdt:P19/wdt:P131* ?dpt ; wdt:P735 ?prenom .
?dpt p:P131/ps:P131 wd:Q1152 ; wdt:P31 wd:Q6465 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?prenomLabel
HAVING ( ?compte > 5 )

 

 

Liste des articles sur Blaise Pascal dans toutes les Wikipédia, classés par taille décroissante de l’article Liste des articles sur Blaise Pascal dans toutes les Wikipédia, classés par taille décroissante de l’article (lien)

#title: Liste des articles sur Blaise Pascal dans toutes les Wikipédia, classés par taille décroissante de l’article

#defaultView:BubbleChart
SELECT ?sitelink ?site ?title ?taille
WHERE
{
?sitelink schema:about wd:Q1290.
?sitelink schema:isPartOf ?site.
?sitelink schema:isPartOf/wikibase:wikiGroup "wikipedia" .
?sitelink schema:name ?title.
BIND (STRBEFORE(STRAFTER(STR(?site), "https://"), "/") AS ?endpoint)
BIND (STR(?title) AS ?title_nolang)
SERVICE wikibase:mwapi
{
bd:serviceParam wikibase:endpoint ?endpoint.
bd:serviceParam wikibase:api "Generator".
bd:serviceParam mwapi:generator "revisions".
bd:serviceParam mwapi:titles ?title_nolang.
bd:serviceParam mwapi:prop "revisions".
bd:serviceParam mwapi:rvprop "size".
?size wikibase:apiOutput "revisions/rev[last()]/@size".
}
BIND ( xsd:integer(?size) AS ?taille )
}
ORDER BY DESC(?taille) 

Personnes présentes dans les calendriers Les Dieux du stade : liste des équipes sportives par nombre de personnes dans ces calendriers

Personnes présentes dans les calendriers Les Dieux du stade : liste des équipes sportives par nombre de personnes dans ces calendriers (lien)

 

#title: Équipes sportives par nombre de personnes présentes dans le calendrier Les Dieux du stade
#defaultView:BubbleChart
SELECT ?équipe ?équipeLabel (COUNT(DISTINCT ?personne) AS ?nb) WHERE {
?edition wdt:P361 wd:Q1452969 ;
wdt:P180 ?personne .
?personne wdt:P54 ?équipe
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?équipe ?équipeLabel  

 

 

Occupation des personnes liées (employés, membres, affiliés) aux universités de Clermont (diagramme en bulle réalisé avec Rawgraphs)

Occupation des personnes liées (employés, membres, affiliés) aux universités de Clermont (diagramme en bulle réalisé avec Rawgraphs) (lien)

#title: Occupation des personnes liées aux universités de Clermont
#defaultView:BubbleChart
SELECT ?occupation1Label (COUNT(DISTINCT ?researcher) AS ?nb) WHERE {
VALUES ?univ { wd:Q1319786 wd:Q1381437 wd:Q612648 wd:Q3551576 }
?researcher (wdt:P108|wdt:P463|wdt:P1416) ?univ .
?researcher wdt:P106 ?occupation1 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?occupation1Label 

 

Nombre d’équipes de rugby françaises selon l’année de création

Nombre d’équipes de rugby françaises selon l’année de création (lien)

#title: Nombre d’équipes de rugby français selon la date de création
#defaultView:BubbleChart
SELECT ?année (COUNT(?équipe) AS ?nombre) WHERE {
?équipe wdt:P31 wd:Q14645593 ;
wdt:P17 wd:Q142 .
OPTIONAL { ?équipe wdt:P571 ?date . }
BIND ( STR(YEAR(?date)) AS ?year )
BIND(IF(BOUND(?year),?year,"sans date") AS ?année)
}
GROUP BY ?année 

Tableaux du musée de Bretagne avec une bulle de taille proportionnelle au nombre de tableaux du peintre Tableaux du musée de Bretagne avec une bulle de taille proportionnelle au nombre de tableaux du peintre (lien)

 

#defaultView:BubbleChart
#title: Tableaux du musée de Bretagne avec une bulle de taille proportionnelle au nombre de tableaux du peintre
SELECT ?creator ?creatorLabel (COUNT(?q) AS ?nb) WHERE {
?q wdt:P195 wd:Q3329701 ;
wdt:P31 wd:Q3305213 ;
wdt:P170 ?creator .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?creator ?creatorLabel

Profession et genre des personnes dont des œuvres sont conservées au musée de BretagneProfession et genre des personnes dont des œuvres sont conservées au musée de Bretagne (lien)

#title:Profession et genre des personnes dont des œuvres sont conservées au musée de Bretagne
#illustrates bubblechart view, count, using ?rgb as color#defaultView:BubbleChart
SELECT ?occupation_fr ?rgb (COUNT(DISTINCT ?person) AS ?personCount) WHERE {
?person wdt:P31 wd:Q5;
wdt:P6379 wd:Q3329701 ;
wdt:P106 ?occupation;
wdt:P21 ?gender.
bind( if(?gender=wd:Q6581097,"94D459","4B1270") as ?rgb ) .
OPTIONAL {?occupation rdfs:label ?occupation_fr filter (lang(?occupation_fr) = "fr")}.
}
GROUP BY ?occupation_fr ?rgb
ORDER BY DESC(?personCount)

 

Nombre de pages des catalogues d'expositions du musée de Bretagne en fonction de leur date de publicationNombres de pages des catalogues d'expositions du musée de Bretagne en fonction de la date de publication (lien)

#defaultView:BarChart
#title: Nombres de pages des catalogues d'expositions du musée de Bretagne en fonction du temps
SELECT ?date ?nb_pages WHERE {
?q wdt:P31 wd:Q29023906 ; #exposition temporaire
wdt:P664 wd:Q3329701 . #organisée par le musée de Bretagne
?ouvrage wdt:P921 ?q ; wdt:P577 ?date ; wdt:P1104 ?nb_pages .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". } #libellés
}

 

Des cartes

 

 

Carte du lieu de mort des personnes nées dans le Puy-de-Dôme

Carte du lieu de mort des personnes nées dans le Puy-de-Dôme (lien)

 

#defaultView:Map
SELECT ?person ?personLabel ?locLabel ?coord WHERE {
?person wdt:P19/wdt:P131* wd:Q12694 ;
wdt:P20 ?loc .
?loc wdt:P625 ?coord .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 

 

 

  Trajet via Wikidata de l'ouvrage « Itinéraire de Paris au mont-d’or » transcrit sur Wikisource

Trajet via Wikidata de l'ouvrage « Itinéraire de Paris au mont-d’or » transcrit sur Wikisource (lien)

 

#defaultView:Map
SELECT ?lieu ?lieuLabel ?layer ?coord WHERE {
wd:Q108366183 p:P840 ?node .
?node ps:P840 ?lieu .
?node pq:P585 ?layer .
?lieu wdt:P625 ?coord .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

 

Carte des voies de Clermont-Ferrand ayant un élément Wikidata et optionnellement un article Wikipédia

Carte des voies de Clermont-Ferrand ayant un élément Wikidata et optionnellement un article Wikipédia (lien)

#defaultView:Map
SELECT ?voie ?voieLabel ?voieDescription ?article ?coord WHERE {
?voie wdt:P31/wdt:P279* wd:Q83620 ; wdt:P131 wd:Q42168 ; wdt:P625 ?coord .
OPTIONAL { ?article schema:about ?voie . ?article schema:isPartOf <https://fr.wikipedia.org/> . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?voieLabel 

 
 

Carte des lieux nommés en référence au cheval

Carte des lieux nommés en référence au cheval (au sens large) (lien)

#defaultView:Map
SELECT ?item ?libellé ?coord ?image ?layer WHERE {
?item wdt:P138 ?type ; wdt:P625 ?coord .
?type wdt:P279* wd:Q726 .
OPTIONAL { ?item wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" .
?type rdfs:label ?layer .
?item rdfs:label ?libellé }
}

 

Carte des villes jumelées (ou partenaires) de communes du Puy-de-Dôme

Carte des villes jumelées (ou partenaires) de communes du Puy-de-Dôme (lien)

#title:Carte des villes jumelées (ou partenaires) de communes du Puy-de-Dôme
#defaultView:Map
SELECT ?commune ?twin ?twinLabel ?layer ?coord WHERE {
?commune wdt:P131+ wd:Q12694 ; wdt:P190 ?twin .
?twin wdt:P625 ?coord .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?commune rdfs:label ?layer }
} 

 

 

Libraries with ISIL identifier / bibliothèque avec un identifiant ISIL

 

Libraries with ISIL identifier / bibliothèque avec un identifiant ISIL (lien)

 

#defaultView:Map
#title: Libraries with ISIL identifier
SELECT * WHERE {
?item wdt:P791 ?id ; wdt:P625 ?coord .
} 

 

sparql wd 1Carte des stations de tramway de Clermont-Ferrand (lien)

 

#title: Carte des stations de tramway de Clermont-Ferrand
#defaultView:MapSELECT ?item ?itemLabel ?coord ?rgb
WHERE
{
SERVICE gas:service {
gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
gas:in wd:Q110597453 ;
gas:out ?item ;
gas:linkType wdt:P197 .
}
?item wdt:P81/wdt:P465 ?rgb. #récupère la couleur officielle
?item wdt:P625 ?coord .
SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" }
}

 

Regardez le code SPARQL pour un exemple simple de service gas bigdata (syntaxe très pratique quand il s'agit de réseaux)

 

Localisation des 59 communes dont le nom fait plus de 30 caractèresLocalisation des 59 communes dont le nom fait plus de 30 caractères (lien)

 

#defaultView:Map
SELECT * WHERE {
?commune wdt:P31 wd:Q484170 ; wdt:P625 ?coord ; rdfs:label ?label .
FILTER ( LANG(?label) = "fr" )
FILTER ( STRLEN(?label) > 30 )
} 

 

 

Carte des lieux de naissance des joueurs de l'ASM (carte zoomable, points cliquables et filtrables par décennie) Carte des lieux de naissance des joueurs de l'ASM (carte zoomable, points cliquables et filtrables par décennie) (lien)

#title: Lieux de naissance des joueurs de l'ASM Clermont Auvergne
#defaultView:Map
SELECT ?item ?itemLabel ?lieu ?date ?coord ?layer ?img WHERE {
?item wdt:P54 wd:Q297901 ;
wdt:P19 ?lieu ;
wdt:P569 ?date .
?lieu wdt:P625 ?coord .
OPTIONAL { ?item wdt:P18 ?img }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
BIND ( CONCAT("Années ",STR(FLOOR(YEAR(?date)/10)),"0") AS ?layer )
} 

 

Carte des autres équipes dont été membres des joueurs de l'ASM (la couleur est fonction du nombre de membres par équipes)Carte des autres équipes dont été membres des joueurs de l'ASM (la couleur est fonction du nombre de membres par équipes) (lien)

 

#title: Équipes dont été membres des joueurs de l'ASM Clermont-Auvergne
#defaultView:Map
SELECT ?autreequipe ?autreequipeLabel ?coord (GROUP_CONCAT(?joueurLabel ; SEPARATOR = ", ") as ?joueurs) (COUNT(?joueur) AS ?layer) WHERE {
?joueur wdt:P54 wd:Q297901 ;
wdt:P54 ?autreequipe .
?autreequipe wdt:P159/wdt:P625 ?coord .
FILTER ( ?autreequipe != wd:Q297901 )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?autreequipe rdfs:label ?autreequipeLabel .
?joueur rdfs:label ?joueurLabel . }
}
GROUP BY ?autreequipe ?autreequipeLabel ?coord 

 

 

 

Carte des lieux de tournages de films tournés dans le Puy-de-DômeCarte des lieux de tournages de films tournés dans le Puy-de-Dôme (lien)

 

#title: Lieux de tournages de films tournés dans le Puy-de-Dôme
#defaultView:Map
SELECT ?film ?filmLabel ?lieu ?lieuLabel ?coord ?layer WHERE {
?film wdt:P915 ?lieu .
?lieu wdt:P131* wd:Q12694 .
?lieu wdt:P625 ?coord .
?film wdt:P577 ?date .
BIND ( year(?date) AS ?layer )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 

 

 

Carte des lieux de création ou de découverte d’objets des collections du musée de BretagneCarte des lieux de création ou de découverte d’objets des collections du musée de Bretagne (lien)

#title: Lieux des objets des collections du musée de Bretagne
#defaultView:Map
SELECT ?q ?qLabel ?img ?locLabel ?coord ?layer WHERE {
?q wdt:P195 wd:Q3329701 ; (wdt:P1071|wdt:P189) ?loc .
OPTIONAL { ?q wdt:P18 ?img }
?q ?lien ?loc . ?lienItem wikibase:directClaim ?lien .
?loc wdt:P625 ?coord .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". ?q rdfs:label ?qLabel . ?lienItem rdfs:label?layer . }
}  

 

 

Cartes des lieux de naissance de femmes en Ille-et-Vilaine (avec et sans photo)Cartes des lieux de naissance de femmes (connues de Wikidata) nées en Ille-et-Vilaine, le point est vert si il y a une photo et gris foncé (lien)

#title: Cartes des lieux de naissance de femmes en Ille-et-Vilaine (avec et sans photo)
#defaultView:Map
SELECT ?personne ?personneLabel ?locLabel ?coord ?rgb WHERE {
?personne wdt:P31 wd:Q5 ;
wdt:P21 wd:Q6581072 ;
wdt:P19 ?loc .
?loc wdt:P131* wd:Q12549 ; wdt:P625 ?coord .
OPTIONAL { ?personne wdt:P18 ?image }
BIND(IF(BOUND(?image),"60BB00","666666") AS ?rgb).
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 

Lieux de Rennes avec un article sur la Wikipédia en françaisLieux de Rennes avec un article sur la Wikipédia en français  (et coloré selon le nombre de page dans l'ensemble des projets Wikimédia) (lien)

#title: Lieux de Rennes avec un article sur la Wikipédia en français
#defaultView:Map
SELECT DISTINCT ?q ?qLabel ?coord ?page ?layer WHERE {
?q wdt:P131+ wd:Q647 ;
wikibase:sitelinks ?layer .
wd:Q647 wdt:P625 ?coordRennes .
SERVICE wikibase:around {
?q wdt:P625 ?coord .
bd:serviceParam wikibase:center ?coordRennes .
bd:serviceParam wikibase:radius "10" .
}
?page schema:about ?q ;
schema:isPartOf <https://fr.wikipedia.org/> .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

Lieux de naissances ou de décès de femmes peintres en BretagneLieux de naissances ou de décès de femmes peintres en Bretagne (lien)

#title: Lieux de naissances ou de décès de femmes peintres
#defaultView:Map
SELECT ?q ?qLabel ?layer ?coord WHERE {
VALUES ?Bretagne { wd:Q3389 wd:Q3349 wd:Q12642 wd:Q12549 wd:Q3068 }
?q wdt:P21 wd:Q6581072 ;
wdt:P106 wd:Q1028181 ;
(wdt:P19|wdt:P20) ?layer .
?layer wdt:P625 ?coord ; wdt:P131* ?Bretagne .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Carte des lieux ayant donnés leur nom à un lieu à RennesCarte des lieux ayant donnés leur nom à un lieu à Rennes (avec type) (lien)

#defaultView:Map
#title: Carte des lieux ayant donnés leur nom à un lieu à Rennes
SELECT ?loc ?locLabel ?item ?itemLabel ?coord ?layer WHERE {
?loc wdt:P131 wd:Q647 ;
wdt:P138 ?item .
?item wdt:P31 ?type ; wdt:P625 ?coord .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?type rdfs:label ?layer }
}

 

Des frises chronologiques

 Frise chronologique des personnes nées dans le Puy-de-Dôme

Frise chronologique des personnes nées dans le Puy-de-Dôme : table brute (lien)

SELECT ?person ?personLabel ?dateN ?dateM ?image ?occupationLabel WHERE {
?person wdt:P19/wdt:P131* wd:Q12694 .
?person wdt:P569 ?dateN .
?person wdt:P570 ?dateM .
OPTIONAL { ?person wdt:P18 ?image }
OPTIONAL { ?person wdt:P106 ?occupation }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

 

Frise interactive visualisée avec Histropedia

 

Frise chronologique des personnes inhumées au cimetière des Carmes (Clermont-Ferrand)

Frise chronologique des personnes inhumées au cimetière des Carmes (Clermont-Ferrand) (lien)

#defaultView:Timeline
SELECT ?person ?personLabel ?dateN ?dateM WHERE {
?person wdt:P119 wd:Q2972588 .
?person wdt:P569 ?dateN .
?person wdt:P570 ?dateM .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

 

 

Autres

 

Etudiants des universités de Clermont et leur généalogie académique

 

Etudiants des universités de Clermont et leur généalogie académique (lien)

#defaultView:Graph
SELECT ?person ?personLabel ?dir ?dirLabel WHERE {
VALUES ?univ { wd:Q1381437 wd:Q612648 wd:Q1319786 wd:Q3551576 }
?person wdt:P69 ?univ .
?person wdt:P184 ?dir .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

 

Requête SPARQL Wikidata : Noms de Clermont-Ferrand dans plusieurs écritures/langues (trié par occurrence) / Names of Clermont-Ferrand in multiple scripts/languages (order by weight) 

Noms de Clermont-Ferrand dans plusieurs écritures/langues (trié par occurrence) / Names of Clermont-Ferrand in multiple scripts/languages (order by weight) (lien)

#title: Noms de Clermont-Ferrand dans plusieurs écritures/langues (trié par occurrence) / Names of Clermont-Ferrand in multiple scripts/languages (order by weight)
SELECT ?word (COUNT(?label) AS ?weight) WHERE {
wd:Q42168 rdfs:label ?label .
BIND ( STR(?label) AS ?word )
}
GROUP BY ?word
ORDER BY DESC(?weight)

 

 

Graphe des relations de quelques artistes irlandais / Graph of relationships of Irish artistsGraphe des relations de quelques artistes irlandais / Graph of relationships of Irish artists (résultats un peu brut, les suggestions d'améliorations sont bienvenues) (lien)

#title: Irish artists and their relationships
#defaultView:Graph
SELECT ?item ?itemLabel ?occupationLabel ?link ?item2 ?item2Label ?image ?image2 WHERE {
{
SELECT * WHERE {
?item wdt:P27 wd:Q27;
wdt:P106 ?occupation.
?occupation wdt:P31 wd:Q88789639.
OPTIONAL { ?item wdt:P18 ?image. }
}
}
?item ?link ?item2.
?item2 wdt:P27 wd:Q27.
OPTIONAL { ?item2 wdt:P18 ?image2. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 

 

 

Pays de nationalité des personnes liées aux universités de Clermont et regroupées par continents (Wikidata et Rawgraphs) 

Pays de nationalité des personnes liées aux universités de Clermont et regroupées par continents (lien)

encore un essai de visualisation avec rawgraphs

#title: Pays de nationalité des personnes liées aux universités de Clermont
SELECT ?lieuLabel ?contLabel (COUNT(DISTINCT ?researcher) AS ?nb) WHERE {
VALUES ?univ { wd:Q1319786 wd:Q1381437 wd:Q612648 wd:Q3551576 }
?researcher (wdt:P108|wdt:P463|wdt:P1416) ?univ .
?researcher wdt:P27 ?lieu .
?lieu wdt:P30 ?cont .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?lieuLabel ?contLabel 

 

 

 

 

Bonus


Query CommonsQuery Commons - Images représentant Clermont-Ferrand (lien)

#defaultView:ImageGrid
select ?file ?image where {
?file wdt:P180/wdt:P131* wd:Q42168 .
?file schema:url ?image .
}

 

 

Personnes liées à Rennes dans Factgrid (lien)

#title: Personnes liées à Rennes
SELECT DISTINCT ?personne ?personneLabel ?page WHERE {
?personne ?prop wd:Q129672 ;
wdt:P2 wd:Q7 .
OPTIONAL { ?page schema:about ?personne ;
schema:isPartOf <https://www.wikidata.org/> }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

 

Comments est propulsé par CComment

À propos

Le numérique c’est fantastique (et non dramatique), surtout quand on travaille dans le domaine du patrimoine.

« C’est compliqué… ». « Je n’ose pas… ». « Je ne sais pas comment faire… »

Nul besoin d’années de code pour se simplifier la vie et le boulot sur un ordinateur. Archiviste et formatrice sur les outils et la médiation numérique, j'ai créé en 2015 ce blog pour partager et diffuser auprès des acteurs des archives et du patrimoine des tutoriels et des outils simples, pratiques et gratuits.

Idées, requêtes, questions, contributions sont les bienvenues.

Maïwenn Bourdic

Derniers articles

Mots-clés

Framasoft (4) 7 zip (1) Calaméo (1) presse (2) outils (1) hackhaton (1) Framapad (2) nommage (1) openrefine (6) affiche (1) médias (5) archives départementales des Côtes-d'Armor (2) données (4) dossier compressé (1) csv (1) Wikidata (8) relevé collaboratif (1) référencement (2) contribuer (1) raccourci clavier (2)